Projektdateien hinzufügen.

Pilz.Collections/SimpleHistory/Enums.vb

@@ -0,0 +1,12 @@
+Namespace SimpleHistory
+
+    ''' <summary>
+    ''' Specify which member types you would include.
+    ''' </summary>
+    Public Enum ObjectValueType
+        None = 0
+        Field = 1
+        [Property] = 2
+    End Enum
+
+End Namespace

Pilz.Collections/SimpleHistory/HistoryPoint.vb

@@ -0,0 +1,543 @@
+Imports System.Reflection
+
+Namespace SimpleHistory
+
+    ''' <summary>
+    ''' Represent some Object States and Actions.
+    ''' </summary>
+    Public Class HistoryPoint
+
+        ''' <summary>
+        ''' Represents the Name of this History Point
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property Name As String = ""
+        ''' <summary>
+        ''' A List of Object States and Actions.
+        ''' </summary>
+        ''' <returns></returns>
+        Public ReadOnly Property Entries As New List(Of ObjectBase)
+        ''' <summary>
+        ''' Some data can be refered on this HistoryPoint. Don't know, in some situations this can be helpful.
+        ''' </summary>
+        Public ReadOnly Tag As Object = Nothing
+
+        Public Function HasEntries(Of T As ObjectBase)() As Boolean
+            Return Entries.Where(Function(n) TypeOf n Is T).Count > 0
+        End Function
+
+        Friend Sub Undo()
+            For Each s As ObjectBase In Entries.OrderBy(Function(n) n.UndoPriority)
+                If TypeOf s Is ObjectState Then
+                    CType(s, ObjectState).Patch()
+                ElseIf TypeOf s Is ObjectAction Then
+                    CType(s, ObjectAction).Undo()
+                End If
+            Next
+        End Sub
+
+        Friend Sub Redo()
+            For Each s As ObjectBase In Entries.OrderBy(Function(n) n.RedoPriority)
+                If TypeOf s Is ObjectState Then
+                    CType(s, ObjectState).Patch()
+                ElseIf TypeOf s Is ObjectAction Then
+                    CType(s, ObjectAction).Redo()
+                End If
+            Next
+        End Sub
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), whiteList As MemberWhiteList) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(whiteList), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), blackList As MemberBlackList) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(blackList), BindingFlags.Default)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberWhiteList(memberName)), BindingFlags.Default)
+            Else
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberBlackList(memberName)), BindingFlags.Default)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), membersToStore As ObjectValueType, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, membersToStore, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), membersToStore As ObjectValueType, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, membersToStore, CObj(New MemberWhiteList(memberName)), BindingFlags.Default)
+            Else
+                Return FromObject({obj}, membersToStore, CObj(New MemberBlackList(memberName)), BindingFlags.Default)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), flags As BindingFlags, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, flags, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), flags As BindingFlags, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberWhiteList(memberName)), flags)
+            Else
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberBlackList(memberName)), flags)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), membersToStore As ObjectValueType, flags As BindingFlags, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, flags, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object(), membersToStore As ObjectValueType, flags As BindingFlags, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, membersToStore, CObj(New MemberWhiteList(memberName)), flags)
+            Else
+                Return FromObject({obj}, membersToStore, CObj(New MemberBlackList(memberName)), flags)
+            End If
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, whiteList As MemberWhiteList) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(whiteList), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, blackList As MemberBlackList) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(blackList), BindingFlags.Default)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberWhiteList(memberName)), BindingFlags.Default)
+            Else
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberBlackList(memberName)), BindingFlags.Default)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, membersToStore, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, membersToStore, CObj(New MemberWhiteList(memberName)), BindingFlags.Default)
+            Else
+                Return FromObject({obj}, membersToStore, CObj(New MemberBlackList(memberName)), BindingFlags.Default)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, flags As BindingFlags, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, flags, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, flags As BindingFlags, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberWhiteList(memberName)), flags)
+            Else
+                Return FromObject({obj}, ObjectValueType.None, CObj(New MemberBlackList(memberName)), flags)
+            End If
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="memberName">The member names to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, flags As BindingFlags, ParamArray memberName As String()) As HistoryPoint
+            Return FromObject(obj, flags, True, memberName)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <param name="isWhiteList">If true, the memberName-Array has member names that should be included.</param>
+        ''' <param name="memberName">The member names to include/exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, flags As BindingFlags, isWhiteList As Boolean, ParamArray memberName As String()) As HistoryPoint
+            If isWhiteList Then
+                Return FromObject({obj}, membersToStore, CObj(New MemberWhiteList(memberName)), flags)
+            Else
+                Return FromObject({obj}, membersToStore, CObj(New MemberBlackList(memberName)), flags)
+            End If
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(Nothing), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(Nothing), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, whiteList As MemberWhiteList) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(whiteList), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, blackList As MemberBlackList) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(blackList), BindingFlags.Default)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, flags As BindingFlags) As HistoryPoint
+            Return FromObject({obj}, ObjectValueType.None, CObj(Nothing), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, flags As BindingFlags) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(Nothing), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, whiteList As MemberWhiteList, flags As BindingFlags) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(whiteList), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="obj">The object that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(obj As Object, membersToStore As ObjectValueType, blackList As MemberBlackList, flags As BindingFlags) As HistoryPoint
+            Return FromObject({obj}, membersToStore, CObj(blackList), flags)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object()) As HistoryPoint
+            Return FromObject(objs, ObjectValueType.None, CObj(Nothing), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(Nothing), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, whiteList As MemberWhiteList) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(whiteList), BindingFlags.Default)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, blackList As MemberBlackList) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(blackList), BindingFlags.Default)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), flags As BindingFlags) As HistoryPoint
+            Return FromObject(objs, ObjectValueType.None, CObj(Nothing), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, flags As BindingFlags) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(Nothing), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="whiteList">Specify which members to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, whiteList As MemberWhiteList, flags As BindingFlags) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(whiteList), flags)
+        End Function
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="blackList">Specify which members to exclude.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Public Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, blackList As MemberBlackList, flags As BindingFlags) As HistoryPoint
+            Return FromObject(objs, membersToStore, CObj(blackList), flags)
+        End Function
+
+        ''' <summary>
+        ''' Creates an History Point with Object States automaticly from input.
+        ''' </summary>
+        ''' <param name="objs">The objects that should be included.</param>
+        ''' <param name="membersToStore">Specify what member types to include.</param>
+        ''' <param name="whiteOrBlackList">Specify which members to include.</param>
+        ''' <param name="flags">The Binding Flags that the members should have.</param>
+        ''' <returns>A History Point with Object States.</returns>
+        Private Shared Function FromObject(objs As Object(), membersToStore As ObjectValueType, whiteOrBlackList As Object, flags As BindingFlags) As HistoryPoint
+            Dim hp As New HistoryPoint
+
+            If whiteOrBlackList Is Nothing Then whiteOrBlackList = New MemberBlackList
+            Dim isWhiteList As Boolean = TypeOf whiteOrBlackList Is MemberWhiteList
+
+            If flags = BindingFlags.Default Then
+                flags = BindingFlags.Instance Or BindingFlags.Public Or BindingFlags.NonPublic
+            End If
+            If membersToStore = ObjectValueType.None Then
+                membersToStore = ObjectValueType.Field Or ObjectValueType.Property
+            End If
+
+            For Each obj As Object In objs
+                If (membersToStore And ObjectValueType.Field) = ObjectValueType.Field Then
+
+                    For Each fi As FieldInfo In obj.GetType.GetFields(flags)
+
+                        Dim contains As Boolean = whiteOrBlackList.Contains(fi.Name)
+                        If If(isWhiteList, contains, Not contains) Then
+
+                            Dim os As New ObjectState
+                            os.Object = obj
+                            os.MemberName = fi.Name
+                            os.MemberType = ObjectValueType.Field
+                            os.MemberFlags = flags
+                            os.ValueToPatch = fi.GetValue(obj)
+                            hp.Entries.Add(os)
+
+                        End If
+
+                    Next
+
+                End If
+
+                If (membersToStore And ObjectValueType.Property) = ObjectValueType.Property Then
+
+                    For Each pi As PropertyInfo In obj.GetType.GetProperties(flags)
+
+                        Dim contains As Boolean = whiteOrBlackList.Contains(pi.Name)
+                        If If(isWhiteList, contains, Not contains) Then
+
+                            Dim os As New ObjectState
+                            os.Object = obj
+                            os.MemberName = pi.Name
+                            os.MemberType = ObjectValueType.Property
+                            os.MemberFlags = flags
+                            os.ValueToPatch = pi.GetValue(obj)
+                            hp.Entries.Add(os)
+
+                        End If
+
+                    Next
+
+                End If
+            Next
+
+            Return hp
+        End Function
+
+        ''' <summary>
+        ''' Combines some History Points to one.
+        ''' </summary>
+        ''' <param name="hps">An array of History Points to combine.</param>
+        ''' <returns>One History Point that contains all Data of inputted History Points.</returns>
+        Public Shared Function Concat(ParamArray hps As HistoryPoint()) As HistoryPoint
+            Return Concat(hps.FirstOrDefault?.Name, hps)
+        End Function
+
+        ''' <summary>
+        ''' Combines some History Points to one.
+        ''' </summary>
+        ''' <param name="hps">An array of History Points to combine.</param>
+        ''' <returns>One History Point that contains all Data of inputted History Points.</returns>
+        Public Shared Function Concat(newName As String, ParamArray hps As HistoryPoint()) As HistoryPoint
+            Dim hp As New HistoryPoint
+
+            For Each _hp As HistoryPoint In hps
+                hp.Entries.AddRange(_hp.Entries)
+            Next
+
+            Return hp
+        End Function
+
+    End Class
+
+End Namespace

Pilz.Collections/SimpleHistory/MemberLists.vb

@@ -0,0 +1,33 @@
+Namespace SimpleHistory
+
+    ''' <summary>
+    ''' List contianing member names to include.
+    ''' </summary>
+    Public Class MemberWhiteList
+        Inherits List(Of String)
+
+        Public Sub New()
+            MyBase.New
+        End Sub
+
+        Public Sub New(entries As String())
+            MyBase.New(entries)
+        End Sub
+    End Class
+
+    ''' <summary>
+    ''' List contianing member names to exclude
+    ''' </summary>
+    Public Class MemberBlackList
+        Inherits List(Of String)
+
+        Public Sub New()
+            MyBase.New
+        End Sub
+
+        Public Sub New(entries As String())
+            MyBase.New(entries)
+        End Sub
+    End Class
+
+End Namespace

Pilz.Collections/SimpleHistory/ObjectAction.vb

@@ -0,0 +1,165 @@
+Imports System.Reflection
+Imports System.Runtime.InteropServices
+
+Namespace SimpleHistory
+
+    Public Class ObjectAction
+        Inherits ObjectBase
+
+        Public Property [Object] As Object = Nothing
+        Public ReadOnly Property ParametersUndo As New List(Of Object)
+        Public ReadOnly Property ParametersRedo As New List(Of Object)
+        Public Property MethodUndo As MethodInfo = Nothing
+        Public Property MethodRedo As MethodInfo = Nothing
+        Public Property AutogenerateObject As Boolean = True
+
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        Public Sub New()
+        End Sub
+
+        Private Function GetMethodInfo(obj As Object, name As String, flags As BindingFlags)
+            Return obj.GetType.GetMethod(name, flags)
+        End Function
+
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodNameUndo">The name of the methode to call on Undo.</param>
+        ''' <param name="methodNameRedo">The name of the methode to call on Redo.</param>
+        Public Sub New(obj As Object, methodNameUndo As String, methodNameRedo As String)
+            Me.New(obj, methodNameUndo, methodNameRedo, {}, {}, BindingFlags.Default, BindingFlags.Default)
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodNameUndo">The name of the methode to call on Undo.</param>
+        ''' <param name="methodNameRedo">The name of the methode to call on Redo.</param>
+        ''' <param name="paramsUndo">The parameters for calling the methode on Undo.</param>
+        ''' <param name="paramsRedo">The parameters for calling the methode on Redo.</param>
+        Public Sub New(obj As Object, methodNameUndo As String, methodNameRedo As String, paramsUndo As Object(), paramsRedo As Object())
+            Me.New(obj, methodNameUndo, methodNameRedo, paramsUndo, paramsRedo, BindingFlags.Default, BindingFlags.Default)
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodNameUndo">The name of the methode to call on Undo.</param>
+        ''' <param name="methodNameRedo">The name of the methode to call on Redo.</param>
+        ''' <param name="paramsUndo">The parameters for calling the methode on Undo.</param>
+        ''' <param name="paramsRedo">The parameters for calling the methode on Redo.</param>
+        ''' <param name="methodFlagsUndo">The Binding Flags of Methode on Undo.</param>
+        ''' <param name="methodFlagsRedo">The Binding Flags of Methode on Redo.</param>
+        Public Sub New(obj As Object, methodNameUndo As String, methodNameRedo As String, paramsUndo As Object(), paramsRedo As Object(), methodFlagsUndo As BindingFlags, methodFlagsRedo As BindingFlags)
+            [Object] = obj
+            ParametersUndo.AddRange(paramsUndo)
+            ParametersRedo.AddRange(paramsRedo)
+            MethodUndo = GetMethodInfo(obj, methodNameUndo, GetFlags(methodFlagsUndo))
+            MethodRedo = GetMethodInfo(obj, methodNameRedo, GetFlags(methodFlagsRedo))
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodNameUndo">The name of the methode to call on Undo.</param>
+        ''' <param name="methodNameRedo">The name of the methode to call on Redo.</param>
+        ''' <param name="methodFlagsUndo">The Binding Flags of Methode on Undo.</param>
+        ''' <param name="methodFlagsRedo">The Binding Flags of Methode on Redo.</param>
+        Public Sub New(obj As Object, methodNameUndo As String, methodNameRedo As String, methodFlagsUndo As BindingFlags, methodFlagsRedo As BindingFlags)
+            Me.New(obj, methodNameUndo, methodNameRedo, {}, {}, methodFlagsUndo, methodFlagsRedo)
+        End Sub
+
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodUndo">The MethodInfo of the methode to call on Undo.</param>
+        ''' <param name="methodRedo">The MethodInfo of the methode to call on Redo.</param>
+        Public Sub New(obj As Object, methodUndo As MethodInfo, methodRedo As MethodInfo)
+            [Object] = obj
+            Me.MethodUndo = methodUndo
+            Me.MethodRedo = methodRedo
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodUndo">The MethodInfo of the methode to call on Undo.</param>
+        ''' <param name="methodRedo">The MethodInfo of the methode to call on Redo.</param>
+        ''' <param name="paramsUndo">The parameters for calling the methode on Undo.</param>
+        ''' <param name="paramsRedo">The parameters for calling the methode on Redo.</param>
+        Public Sub New(obj As Object, methodUndo As MethodInfo, methodRedo As MethodInfo, paramsUndo As Object(), paramsRedo As Object())
+            Me.New(obj, methodUndo, methodRedo)
+            ParametersUndo.AddRange(paramsUndo)
+            ParametersRedo.AddRange(paramsRedo)
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodUndo">The Delegate of the methode to call on Undo.</param>
+        ''' <param name="methodRedo">The Delegate of the methode to call on Redo.</param>
+        Public Sub New(obj As Object, methodUndo As [Delegate], methodRedo As [Delegate])
+            [Object] = obj
+            Me.MethodUndo = methodUndo.Method
+            Me.MethodRedo = methodRedo.Method
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodUndo">The Delegate of the methode to call on Undo.</param>
+        ''' <param name="methodRedo">The Delegate of the methode to call on Redo.</param>
+        ''' <param name="paramsUndo">The parameters for calling the methode on Undo.</param>
+        ''' <param name="paramsRedo">The parameters for calling the methode on Redo.</param>
+        Public Sub New(obj As Object, methodUndo As [Delegate], methodRedo As [Delegate], paramsUndo As Object(), paramsRedo As Object())
+            Me.New(obj, methodUndo, methodRedo)
+            ParametersUndo.AddRange(paramsUndo)
+            ParametersRedo.AddRange(paramsRedo)
+        End Sub
+        ''' <summary>
+        ''' Creates a new Instance of Object Action.
+        ''' </summary>
+        ''' <param name="obj">The Objects that contains the methodes to call.</param>
+        ''' <param name="methodUndo">The Action of the methode to call on Undo.</param>
+        ''' <param name="methodRedo">The Action of the methode to call on Redo.</param>
+        Public Sub New(obj As Object, methodUndo As Action, methodRedo As Action)
+            [Object] = obj
+            Me.MethodUndo = methodUndo.Method
+            Me.MethodRedo = methodRedo.Method
+        End Sub
+
+        Private Function GetFlags(flags As BindingFlags) As BindingFlags
+            If flags = BindingFlags.Default Then
+                flags = BindingFlags.Instance Or BindingFlags.Public Or BindingFlags.NonPublic
+            End If
+            Return flags
+        End Function
+
+        Friend Sub Undo()
+            CheckIfObjIsNothing(MethodUndo)
+            MethodUndo?.Invoke([Object], ParametersUndo.ToArray)
+        End Sub
+
+        Friend Sub Redo()
+            CheckIfObjIsNothing(MethodRedo)
+            MethodRedo?.Invoke([Object], ParametersRedo.ToArray)
+        End Sub
+
+        Private Sub CheckIfObjIsNothing(mi As MethodInfo)
+            If mi IsNot Nothing AndAlso Not mi.IsStatic AndAlso AutogenerateObject Then
+                If (Me.Object Is Nothing OrElse Me.Object.GetType <> mi.ReflectedType) AndAlso Not mi.IsStatic Then
+                    Dim constructor As ConstructorInfo = mi.ReflectedType.GetConstructor(Type.EmptyTypes)
+                    Dim classObject As Object = constructor.Invoke({})
+                    Me.Object = classObject
+                End If
+            End If
+        End Sub
+
+    End Class
+
+
+End Namespace

Pilz.Collections/SimpleHistory/ObjectBase.vb

@@ -0,0 +1,13 @@
+Namespace SimpleHistory
+
+    Public Class ObjectBase
+
+        Public Shared Property DefaultPriorityValue As Integer = 1000
+
+        Public Property UndoPriority As Integer = DefaultPriorityValue
+        Public Property RedoPriority As Integer = DefaultPriorityValue
+
+    End Class
+
+
+End Namespace

Pilz.Collections/SimpleHistory/ObjectState.vb

@@ -0,0 +1,84 @@
+Imports System.Reflection
+
+Namespace SimpleHistory
+
+    Public Class ObjectState
+        Inherits ObjectBase
+
+        ''' <summary>
+        ''' The Object including the members to patch.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property [Object] As Object = Nothing
+        ''' <summary>
+        ''' The name of the Member to patch.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property MemberName As String = ""
+        ''' <summary>
+        ''' The Value that should be patched.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property ValueToPatch As Object = Nothing
+        ''' <summary>
+        ''' The member types to include at searching for the member.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property MemberType As ObjectValueType = ObjectValueType.Field
+        ''' <summary>
+        ''' The Binding Flags that are used at searching for the member.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Property MemberFlags As BindingFlags = BindingFlags.Default
+
+        ''' <summary>
+        ''' Creates a new Instance of ObjectState from input.
+        ''' </summary>
+        ''' <param name="obj">The Object including the members to patch.</param>
+        ''' <param name="valname">The name of the Member to patch.</param>
+        ''' <param name="valToPatch">The member types to include at searching for the member.</param>
+        ''' <param name="valtype">The Binding Flags that are used at searching for the member.</param>
+        Public Sub New(obj As Object, valname As String, valToPatch As Object, valtype As ObjectValueType)
+            [Object] = obj
+            MemberName = valname
+            ValueToPatch = valToPatch
+            MemberType = valtype
+        End Sub
+
+        ''' <summary>
+        ''' Creates a new Instance of ObjectState.
+        ''' </summary>
+        Public Sub New()
+        End Sub
+
+        Friend Sub Patch()
+            Dim t As Type = [Object].GetType
+            Select Case MemberType
+                Case ObjectValueType.Field
+                    Dim f As FieldInfo = t.GetField(MemberName, MemberFlags)
+                    Dim temp As Object = Nothing
+
+                    If f IsNot Nothing Then
+                        temp = f.GetValue([Object])
+                        f.SetValue([Object], ValueToPatch)
+                        ValueToPatch = temp
+                    End If
+
+                Case ObjectValueType.Property
+                    Dim p As PropertyInfo = t.GetProperty(MemberName, BindingFlags.Instance Or BindingFlags.Public Or BindingFlags.NonPublic Or BindingFlags.Static)
+                    Dim temp As Object = Nothing
+
+                    If p IsNot Nothing Then
+                        temp = p.GetValue([Object])
+                        p.SetValue([Object], ValueToPatch)
+                        ValueToPatch = temp
+                    End If
+
+                Case Else
+                    Throw New Exception("ValueType is invalid!")
+            End Select
+        End Sub
+
+    End Class
+
+End Namespace

Pilz.Collections/SimpleHistory/SimpleHistory.vb

@@ -0,0 +1,89 @@
+Imports System.Reflection
+
+Namespace SimpleHistory
+
+    Public Class HistoryStack
+
+        Private stackPast As New Stack(Of HistoryPoint)
+        Private stackFuture As New Stack(Of HistoryPoint)
+
+        ''' <summary>
+        ''' Checks if the History has past changes.
+        ''' </summary>
+        ''' <returns></returns>
+        Public Function HasChanges() As Boolean
+            Return stackPast.Count > 0
+        End Function
+
+        ''' <summary>
+        ''' Patch Object States and call Undo Actions.
+        ''' </summary>
+        Public Function Undo() As HistoryPoint
+            Dim ret As HistoryPoint
+
+            If stackPast.Count > 0 Then
+
+                Dim hp As HistoryPoint = stackPast.Pop
+                hp.Undo()
+                stackFuture.Push(hp)
+                ret = hp
+
+            Else
+                ret = Nothing
+
+            End If
+
+            Return ret
+        End Function
+
+        ''' <summary>
+        ''' Patch Object States and call Redo Actions.
+        ''' </summary>
+        Public Function Redo() As HistoryPoint
+            Dim ret As HistoryPoint
+
+            If stackFuture.Count > 0 Then
+
+                Dim hp As HistoryPoint = stackFuture.Pop
+                hp.Redo()
+                stackPast.Push(hp)
+                ret = hp
+
+            Else
+                ret = Nothing
+
+            End If
+
+            Return ret
+        End Function
+
+        ''' <summary>
+        ''' Clear the History.
+        ''' </summary>
+        Public Sub Clear()
+            stackPast.Clear()
+            stackFuture.Clear()
+        End Sub
+
+        ''' <summary>
+        ''' Store a History Point.
+        ''' </summary>
+        ''' <param name="point">The History Point to add to the past changes.</param>
+        ''' <param name="newName">The name to set for the History Point.</param>
+        Public Sub Store(point As HistoryPoint, newName As String)
+            point.Name = newName
+            Store(point)
+        End Sub
+
+        ''' <summary>
+        ''' Store a History Point.
+        ''' </summary>
+        ''' <param name="point">The History Point to add to the past changes.</param>
+        Public Sub Store(point As HistoryPoint)
+            stackPast.Push(point)
+            stackFuture.Clear()
+        End Sub
+
+    End Class
+
+End Namespace